# FindSDL_image

Finds the SDL_image library that loads images of various formats as SDL (Simple DirectMedia Layer) surfaces.

Note

This module is specifically intended for SDL_image version 1. Starting with version 2.6, SDL_image provides a CMake package configuration file when built with CMake and should be found using `find_package(SDL2_image)`. Similarly, SDL_image version 3 can be found using `find_package(SDL3_image)`. These newer versions provide Imported Targets that encapsulate usage requirements. Refer to the official SDL documentation for more information.

## Result Variables

This module defines the following variables:

`SDL_image_FOUND`

  Boolean indicating whether the (requested version of) SDL_image library is found. For backward compatibility, the `SDL_IMAGE_FOUND` variable is also set to the same value.

`SDL_IMAGE_VERSION_STRING`

  The human-readable string containing the version of SDL_image found.

`SDL_IMAGE_INCLUDE_DIRS`

  Include directories containing headers needed to use the SDL_image library.

`SDL_IMAGE_LIBRARIES`

  Libraries needed to link against to use the SDL_image library.

## Hints

This module accepts the following variables:

`SDLDIR`

  Environment variable that can be set to help locate an SDL library installed in a custom location. It should point to the installation destination that was used when configuring, building, and installing SDL library: `./configure --prefix=$SDLDIR`.

## Deprecated Variables

For backward compatibility the following variables are also set:

`SDLIMAGE_FOUND`

  Deprecated since version 2.8.10: Use the `SDL_image_FOUND`, which has the same value.

`SDLIMAGE_INCLUDE_DIR`

  Deprecated since version 2.8.10: Use the `SDL_IMAGE_INCLUDE_DIRS`, which has the same value.

`SDLIMAGE_LIBRARY`

  Deprecated since version 2.8.10: Use the `SDL_IMAGE_LIBRARIES`, which has the same value.

## Examples

Finding SDL_image library and creating an imported interface target for linking it to a project target:

    find_package(SDL_image)

    if(SDL_image_FOUND AND NOT TARGET SDL::SDL_image)
      add_library(SDL::SDL_image INTERFACE IMPORTED)
      set_target_properties(
        SDL::SDL_image
        PROPERTIES
          INTERFACE_INCLUDE_DIRECTORIES "${SDL_IMAGE_INCLUDE_DIRS}"
          INTERFACE_LINK_LIBRARIES "${SDL_IMAGE_LIBRARIES}"
      )
    endif()

    target_link_libraries(project_target PRIVATE SDL::SDL_image)

When working with SDL_image version 2, the upstream package provides the `SDL2_image::SDL2_image` imported target directly. It can be used in a project without using this module:

    find_package(SDL2_image)
    target_link_libraries(project_target PRIVATE SDL2_image::SDL2_image)

Similarly, for SDL_image version 3:

    find_package(SDL3_image)
    target_link_libraries(project_target PRIVATE SDL3_image::SDL3_image)

## See Also

- The `FindSDL` module to find the main SDL library.